'// <SCRIPT language=vbscript>
'// Funcion que dado un numero ansi devuelve un char
function ClsI_char(pValue)
	ClsI_char = chr(pValue)
end function
	
'// Funcion replace
function ClsI_rep(pValue,pStr1,pStr2)
	ClsI_rep = replace(pValue,pStr1,pStr2)
end function

'// Convierte una cadena de fecha dd/mm/aaaa a date
function ClsI_str2date(pValue)
	if pValue<>"" then
		dim lAno,lMes,lDia,x1,x2
		x1=instr(pValue,"/")
		lDia=Left(pValue,X1-1)
		x2=instr(X1+1,pValue,"/")
		lMes=mid(pValue,X1+1,X2-X1-1)
		lAno=mid(pValue,X2+1)
		if lDia="" or lMes="" or lAno="" then
			ClsI_str2date=-1
		elseif CLng(lAno)>2999 then
			ClsI_str2date=-1
		else
			ClsI_str2date=DateSerial(Clng(lAno),CLng(lMes),CLng(lDia))
			if CInt(lDia)<>Day(ClsI_str2date) or CInt(lMes)<>Month(ClsI_str2date) then ClsI_str2date=-1
		end if
	else
		ClsI_str2date=-1
	end if
end function

'// Dado el identificador calcula y devuelve la letra clave
Function ClsI_IDLetra(p_identificador)
  Dim l_i , l_lg 
  Dim l_total
  Dim l_letra, l_id , l_mani, l_desc
  Dim l_mane
		  
  l_id = p_identificador
  l_total = 0

  l_lg = Len(l_id)
  For l_i = 1 To l_lg
    l_total = l_total + Ascb(Mid(l_id, l_i, 1))
  Next
		  
  l_total = (l_total Mod 23) + 65
  If "MANE" = Mid(p_identificador, 6, 4) Then
    l_total = l_total + 1
    If l_total = 91 Then l_total = 65
  End If
  l_letra = Chr(l_total)

  Select Case l_letra
    Case "I"
         l_letra = "X"
    Case "O"
         l_letra = "Y"
    Case "Q"
         l_letra = "Z"
  End Select
  ClsI_IDLetra = l_letra
End Function


'// Dado el identificador verifica si es correcto o no
Function ClsI_ValID(p_str, p_adu, p_tdoc)
  Dim l_letra
  Dim l_numero
  Dim l_res
  l_res = 0

  If Len(p_str) <> 16 Then
    l_res = -1
  Else
    If Not IsNumeric(Mid(p_str, 1, 2)) _
       Or (p_adu  <> "" And Mid(p_str, 3, 3) <> p_adu) _
       Or (p_tdoc <> "" And Mid(p_str, 6, 4) <> p_tdoc) _
       Or Not IsNumeric(Mid(p_str, 10, 6)) Then
		l_res = -1
		if (p_adu  <> "" And p_adu <> Mid(p_str, 3, 3)) then
			l_res = -2
		elseif (p_tdoc  <> "" And Mid(p_str, 6, 4) <> p_tdoc) then
			l_res = -3
		end if
    Else
      l_numero = Left(p_str, 15)
      l_letra = Mid(p_str, 16, 1)
      If ClsI_IDLetra(l_numero) <> ucase(l_letra) Then
         l_res = -1
      End If
    End If
  End If
  ClsI_ValID = l_res
End Function